Comando Linux sed

Em sistemas operacionais do tipo Unix, sed é um editor de fluxo : filtra e transforma texto .

Este documento cobre a versão GNU / Linux do sed .

Descrição

sed é um editor de stream . Um editor de fluxo é usado para executar transformações básicas de texto em um fluxo de entrada (um arquivo ou entrada de um pipeline ). Embora, de certa forma, semelhante a um editor que permita edições com script (como ed ), o sed funcione fazendo apenas uma passagem sobre a (s) entrada (s) e, consequentemente, seja mais eficiente. Mas é a capacidade do sed de filtrar texto em um pipeline que o distingue particularmente de outros tipos de editores.

Sintaxe

OPÇÕES sed ... [ SCRIPT ] [ INPUTFILE ...]

Se você não especificar INPUTFILE , ou se INPUTFILE for ” – “, sed filtra o conteúdo da entrada padrão . O script é, na verdade, o primeiro parâmetro não opcional , que sed considera especialmente um script e não um arquivo de entrada se e somente se nenhuma das outras opções especificar um script a ser executado (ou seja, se nenhuma das opções -e e -f opções está especificada).

Opções

Sed programas

Um programa sed consiste em um ou mais comandos sed , passados ​​por uma ou mais das opções -e , -f , –expression e –file , ou o primeiro argumento de não opção, se nenhuma dessas opções for usada. Esta documentação freqüentemente se refere ao ” sed ” script; isso deve ser entendido como a catenação em ordem de todos os scripts e arquivos de script transmitidos.

Os comandos em um script ou arquivo de script podem ser separados por ponto e vírgula (” ; “) ou novas linhas ( código ASCII 10). Alguns comandos, devido à sua sintaxe , não podem ser seguidos por ponto-e-vírgula trabalhando como separadores de comando e, portanto, devem ser finalizados com novas linhas ou ser colocados no final de um script ou arquivo de script. Os comandos também podem ser precedidos com caracteres de espaço em branco não significativos opcionais .

Cada comando sed consiste em um endereço ou intervalo de endereços opcional (por exemplo, números de linha que especificam em qual parte do arquivo operar; consulte Selecionando Linhas para obter detalhes), seguido por um nome de comando de um caractere e qualquer código adicional específico de comando.

Como funciona o sed

O sed mantém dois buffers de dados: o espaço padrão ativo e o espaço de retenção auxiliar . Ambos estão inicialmente vazios.

sed opera executando o seguinte ciclo em cada linha de entrada: primeiro, sed lê uma linha do fluxo de entrada, remove qualquer nova linha à direita e a coloca no espaço do padrão. Então os comandos são executados; cada comando pode ter um endereço associado a ele: os endereços são um tipo de código de condição e um comando é executado apenas se a condição for verificada antes da execução do comando.

Quando o final do script é atingido, a menos que a opção -n esteja em uso, o conteúdo do espaço do padrão é impresso no fluxo de saída, adicionando novamente a nova linha à direita se ela tiver sido removida. Em seguida, o próximo ciclo inicia para a próxima linha de entrada.

A menos que comandos especiais (como ‘ D ‘) sejam usados, o espaço do padrão é excluído entre dois ciclos. O espaço de espera, por outro lado, mantém seus dados entre os ciclos (consulte os comandos ‘ h ‘, ‘ H ‘, ‘ x ‘, ‘ g ‘, ‘ G ‘ para mover dados entre os dois buffers).

Selecionando linhas com sed

Os endereços em um script sed podem estar em qualquer uma das seguintes formas:

If no addresses are given, then all lines are matched; if one address is given, then only lines matching that address are matched.

An address range can be specified by specifying two addresses separated by a comma (“,“). An address range matches lines starting from where the first address matches, and continues until the second address matches (inclusively).

If the second address is a regexp, then checking for the ending match will start with the line following the line which matched the first address: a range will always span at least two lines (except of course if the input stream ends).

If the second address is a number less than (or equal to) the line matching the first address, then only the one line is matched.

GNU sed also supports some special two-address forms; all these are GNU extensions:

Appending the ! character to the end of an address specification negates the sense of the match. That is, if the ! character follows an address range, then only lines which do not match the address range will be selected. This also works for singleton addresses, and, perhaps perversely, for the null address.

Overview Of Regular Expression Syntax

To know how to use sed, you should understand regular expressions (“regexp” for short). A regular expression is a pattern that is matched against a subject string from left to right. Most characters are ordinary: they stand for themselves in a pattern, and match the corresponding characters in the subject. As a simple example, the pattern

The quick brown fox

…matches a portion of a subject string that is identical to itself. The power of regular expressions comes from the ability to include alternatives and repetitions in the pattern. These are encoded in the pattern by the use of special characters, which do not stand for themselves but instead are interpreted in some special way. Here is a brief description of regular expression syntax as used in sed:

Note that the regular expression matcher is greedy, i.e., matches are attempted from left to right and, if two or more matches are possible starting at the same character, it selects the longest.

For example:

Often-Used Commands

If you use sed at all, you will probably want to know these commands.

The s Command

The syntax of the s command (which stands for “substitute”) is: ‘s/regexp/replacement/flags’. The / characters may be uniformly replaced by any other single character within any given s command. The / character (or whatever other character is used in its stead) can appear in the regexp or replacement only if it is preceded by a \ character.

The s command is probably the most important in sed and has a lot of different options. Its basic concept is simple: the s command attempts to match the pattern space against the supplied regexp; if the match is successful, then that portion of the pattern space which was matched is replaced with replacement.

The replacement can contain \n (n being a number from 1 to 9, inclusive) references, which refer to the portion of the match that is contained between the nth \( and its matching \). Also, the replacement can contain unescaped & characters which reference the whole matched portion of the pattern space. Finally, as a GNU sed extension, you can include a special sequence made of a backslash and one of the letters L, l, U, u, or E. The meaning is as follows:

Para incluir uma linha literal \ , & ou nova linha na substituição final, certifique-se de preceder a linha \ , & ou nova linha desejada na substituição com a \ .

O comando s pode ser seguido por zero ou mais dos seguintes sinalizadores:

Comandos menos usados

Embora talvez seja menos usado do que os da seção anterior, alguns scripts sed muito pequenos, porém úteis, podem ser criados com esses comandos.

Commands for sed gurus

In most cases, use of these commands indicates that you are probably better off programming in something like awk or Perl. But occasionally one is committed to sticking with sed, and these commands can enable one to write quite convoluted scripts.

Commands Specific to GNU sed

These commands are specific to GNU sed, so you must use them with care and only when you are sure that the script will not need to be ported. They allow you to check for GNU sed extensions or to do tasks that are required quite often, yet are unsupported by standard seds.

GNU Extensions for Escapes in Regular Expressions

Until now (in this document, anyway), we have only encountered escapes of the form ‘\^’, for example, which tell sed not to interpret the circumflex (caret) as a special character, but rather to take it literally. For another example, ‘\*’ matches a single asterisk rather than zero or more backslashes.

This section introduces another kind of escape—that is, escapes that are applied to a character or sequence of characters that ordinarily are taken literally, and that sed replaces with a special character. This provides a way of encoding non-printable characters in patterns in a visible manner. There is no restriction on the appearance of non-printing characters in a sed script but when a script is being prepared in the shell or by text editing, it is usually easier to use one of the following escape sequences than the binary character it represents:

‘\b’ (backspace) was omitted because of the conflict with the existing “word boundary” meaning.

Other escapes match a particular character class and are valid only in regular expressions:

Some Sample Scripts

Here are some sed scripts to guide you in the art of mastering sed.

Sample Script: Centering Lines

This script centers all lines of a file on 80 columns width. To change that width, the number in \{…\} must be replaced, and the number of added spaces also must be changed.

Note how the buffer commands are used to separate parts in the regular expressions to be matched—this is a common technique.

#!/usr/bin/sed -f
   
# Put 80 spaces in the buffer
1 {
  x
  s/^$/          /
  s/^.*$/&&&&&&&&/
  x
}
# del leading and trailing spaces
y/tab/ /
s/^ *//
s/ *$//
# add a newline and 80 spaces to end of line
G
# keep first 81 chars (80 + a newline)
s/^\(.\{81\}\).*$/\1/
# \2 matches half of the spaces, which are moved to the beginning
s/^\(.*\)\n\(.*\)\2/\2\1/

Sample Script: Increment A Number

This script is one of a few that demonstrate how to do arithmetic in sed. This script is indeed possible, but must be done manually.

To increment one number you just add 1 to last digit, replacing it by the following digit. There is one exception: when the digit is a nine the previous digits must be also incremented until you don’t have a nine.

This solution is very clever and smart because it uses a single buffer; if you don’t have this limitation, the algorithm used in Numbering Lines is faster. It works by replacing trailing nines with an underscore, then using multiple s commands to increment the last digit, and then again substituting underscores with zeros.

#!/usr/bin/sed -f
/[^0-9]/ d
# replace all leading 9s by _ (any other character except digits, could
# be used)
:d
s/9\(_*\)$/_\1/
td
# incr last digit only.  The first line adds a most-significant
# digit of 1 if we have to add a digit.
#
# The tn commands are not necessary, but make the thing
# faster
s/^\(_*\)$/1\1/; tn
s/8\(_*\)$/9\1/; tn
s/7\(_*\)$/8\1/; tn
s/6\(_*\)$/7\1/; tn
s/5\(_*\)$/6\1/; tn
s/4\(_*\)$/5\1/; tn
s/3\(_*\)$/4\1/; tn
s/2\(_*\)$/3\1/; tn
s/1\(_*\)$/2\1/; tn
s/0\(_*\)$/1\1/; tn
:n
y/_/0/

Sample Script: Rename Files To Lower Case

This script is a pretty strange use of sed. We transform text, and transform it to be shell commands, then just feed them to shell. Don’t worry, even worse hacks are done when using sed. Scripts have even been written converting the output of date into a bc program… So, stranger things have happened.

The main body of this is the sed script, which remaps the name from lower to upper (or vice-versa) and even checks out if the remapped name is the same as the original name. Note how the script is parameterized using shell variables and proper quoting.

#! /bin/sh
# rename files to lower/upper case...
#
# usage:
#    move-to-lower *
#    move-to-upper *
# or
#    move-to-lower -R .
#    move-to-upper -R .
#
help()
{
        cat << eof
Usage: $0 [-n] [-r] [-h] files...
-n      do nothing, only see what would be done
-R      recursive (use find)
-h      this message
files   files to remap to lower case
Examples:
       $0 -n *        (see if everything is ok, then...)
       $0 *
       $0 -R .
eof
}
apply_cmd='sh'
finder='echo "$@" | tr " " "\n"'
files_only=
while :
do
    case "$1" in
        -n) apply_cmd='cat' ;;
        -R) finder='find "$@" -type f';;
        -h) help ; exit 1 ;;
        *) break ;;
    esac
    shift
done
if [ -z "$1" ]; then
        echo Usage: $0 [-h] [-n] [-r] files...
        exit 1
fi
LOWER='abcdefghijklmnopqrstuvwxyz'
UPPER='ABCDEFGHIJKLMNOPQRSTUVWXYZ'
case `basename $0` in
        *upper*) TO=$UPPER; FROM=$LOWER ;;
        *)       FROM=$UPPER; TO=$LOWER ;;
esac
eval $finder | sed -n '
# remove all trailing slashes
s/\/*$//
# add ./ if there is no path, only a file name
/\//! s/^/.\//
# save path+file name
h
# remove path
s/.*\///
# do conversion only on file name
y/'$FROM'/'$TO'/
# now line contains original path+file, while
# hold space contains the new file name
x
# add converted file name to line, which now contains
# path/file-name\nconverted-file-name
G
# check if converted file name is equal to original file name,
# if it is, do not print nothing
/^.*\/\(.*\)\n\1/b
# now, transform path/fromfile\n, into
# mv path/fromfile path/tofile and print it
s/^\(.*\/\)\(.*\)\n\(.*\)$/mv "\1\2" "\1\3"/p
' | $apply_cmd

Sample Script: Print bash Environment

This script strips the definition of the shell functions from the output of the set command in the Bourne-Again shell (bash).

#!/bin/bash
set | sed -n '
:x
# if no occurrence of ‘=()’ print and load next line
/=()/! { p; b; }
/ () $/! { p; b; }
# possible start of functions section
# save the line in case this is a var like FOO="() "
h
# if the next line has a brace, we quit because
# nothing comes after functions
n
/^{/ q
# print the old line
x; p
# work on the new line now
x; bx
'

Sample Script: Reverse Characters Of Lines

This script can be used to reverse the position of characters in lines. The technique moves two characters at a time, hence it is faster than more intuitive implementations.

Note the tx command before the definition of the label. This command is often needed to reset the flag that is tested by the t command.

#!/usr/bin/sed -f
/../! b
# Reverse a line.  Begin embedding the line between two newlines
s/^.*$/\
&\
/
# Move first character at the end.  The regexp matches until
# there are zero or one characters between the markers
tx
:x
s/\(\n.\)\(.*\)\(.\n\)/\3\2\1/
tx
# Remove the newline markers
s/\n//g

Sample Script: Reverse Lines Of Files

This one begins a series of totally useless (yet interesting) scripts emulating various Unix commands. This, in particular, is a tac workalike.

Note that on implementations other than GNU sed this script might easily overflow internal buffers.

#!/usr/bin/sed -nf
# reverse all lines of input, i.e. first line became last, ...
# from the second line, the buffer (which contains all previous lines)
# is *appended* to current line, so, the order will be reversed
1! G
# on the last line we're done -- print everything
$ p
# store everything on the buffer again
h

Sample Script: Numbering Lines

This script replaces ‘cat -n’; in fact it formats its output exactly like GNU cat does.

Of course this is completely useless for two reasons: first, because somebody else did it in C (the cat command), and second, because the following Bourne-shell script could be used for the same purpose and would be much faster:

#! /bin/sh
sed -e "=" $@ | sed -e '
  s/^/      /
  N
  s/^ *\(......\)\n/\1  /
'

It uses sed to print the line number, then groups lines two by two using N. Of course, this script does not teach as much as the one presented below.

The algorithm used for incrementing uses both buffers, so the line is printed as soon as possible and then discarded. The number is split so that changing digits go in a buffer and unchanged ones go in the other; the changed digits are modified in a single step (using a y command). The line number for the next line is then composed and stored in the hold space, to be used in the next iteration.

#!/usr/bin/sed -nf
# Prime the pump on the first line
x
/^$/ s/^.*$/1/
# Add the correct line number before the pattern
G
h
# Format it and print it
s/^/      /
s/^ *\(......\)\n/\1  /p
# Get the line number from hold space; add a zero
# if we're going to add a digit on the next line
g
s/\n.*$//
/^9*$/ s/^/0/
# separate changing/unchanged digits with an x
s/.9*$/x&/
# keep changing digits in hold space
h
s/^.*x//
y/0123456789/1234567890/
x
# keep unchanged digits in pattern space
s/x.*$//
# compose the new number, remove the newline implicitly added by G
G
s/\n//
h

Sample Script: Numbering Non-Blank Lines

Emulating ‘cat -b’ is almost the same as ‘cat -n’: we only have to select which lines are to be numbered and which are not.

The part that is common to this script and the previous one is not commented to show how important it is to comment sed scripts properly…

#!/usr/bin/sed -nf
/^$/ {
  p
  b
}
# Same as cat -n from now
x
/^$/ s/^.*$/1/
G
h
s/^/      /
s/^ *\(......\)\n/\1  /p
x
s/\n.*$//
/^9*$/ s/^/0/
s/.9*$/x&/
h
s/^.*x//
y/0123456789/1234567890/
x
s/x.*$//
G
s/\n//
h

Sample Script: Counting Characters

This script shows another way to do arithmetic with sed. In this case we have to add possibly large numbers, so implementing this by successive increments would not be feasible (and possibly even more complicated to contrive than this script).

The approach is to map numbers to letters, kind of an abacus implemented with sed. ‘a‘s are units, ‘b‘s are tens and so on: we add the number of characters on the current line as units, and then propagate the carry to tens, hundreds, and so on.

As usual, running totals are kept in hold space.

On the last line, we convert the abacus form back to decimal. For the sake of variety, this is done with a loop rather than with some 80 s commands: first we convert units, removing ‘a‘s from the number; then we rotate letters so that tens become ‘a‘s, and so on until no more letters remain.

#!/usr/bin/sed -nf
# Add n+1 a's to hold space (+1 is for the newline)
s/./a/g
H
x
s/\n/a/
# Do the carry.  The t's and b's are not necessary,
# but they do speed up the thing
t a
: a;  s/aaaaaaaaaa/b/g; t b; b done
: b;  s/bbbbbbbbbb/c/g; t c; b done
: c;  s/cccccccccc/d/g; t d; b done
: d;  s/dddddddddd/e/g; t e; b done
: e;  s/eeeeeeeeee/f/g; t f; b done
: f;  s/ffffffffff/g/g; t g; b done
: g;  s/gggggggggg/h/g; t h; b done
: h;  s/hhhhhhhhhh//g
: done
$! {
  h
  b
}
# On the last line, convert back to decimal
: loop
/a/! s/[b-h]*/&0/
s/aaaaaaaaa/9/
s/aaaaaaaa/8/
s/aaaaaaa/7/
s/aaaaaa/6/
s/aaaaa/5/
s/aaaa/4/
s/aaa/3/
s/aa/2/
s/a/1/
: next
y/bcdefgh/abcdefg/
/[a-h]/ b loop
p

Sample Script: Counting Words

This script is almost the same as the previous one, once each of the words on the line is converted to a single ‘a’ (in the previous script each letter was changed to an ‘a’).

It is interesting that real wc programs have optimized loops for ‘wc -c’, so they are much slower at counting words rather than characters. This script’s bottleneck, instead, is arithmetic, and hence the word-counting one is faster (it has to manage smaller numbers).

Again, the common parts are not commented to show the importance of commenting sed scripts.

#!/usr/bin/sed -nf
# Convert words to a's
s/[ tab][ tab]*/ /g
s/^/ /
s/ [^ ][^ ]*/a /g
s/ //g
# Append them to hold space
H
x
s/\n//
# From here on it is the same as in wc -c.
/aaaaaaaaaa/! bx;   s/aaaaaaaaaa/b/g
/bbbbbbbbbb/! bx;   s/bbbbbbbbbb/c/g
/cccccccccc/! bx;   s/cccccccccc/d/g
/dddddddddd/! bx;   s/dddddddddd/e/g
/eeeeeeeeee/! bx;   s/eeeeeeeeee/f/g
/ffffffffff/! bx;   s/ffffffffff/g/g
/gggggggggg/! bx;   s/gggggggggg/h/g
s/hhhhhhhhhh//g
:x
$! { h; b; }
:y
/a/! s/[b-h]*/&0/
s/aaaaaaaaa/9/
s/aaaaaaaa/8/
s/aaaaaaa/7/
s/aaaaaa/6/
s/aaaaa/5/
s/aaaa/4/
s/aaa/3/
s/aa/2/
s/a/1/
y/bcdefgh/abcdefg/
/[a-h]/ by
p

Sample Script: Counting Lines

Sed gives us ‘wc -l’ functionality for free. Here is the code:

#!/usr/bin/sed -nf
$=

Sample Script: Printing The First Lines

This script is probably the simplest useful sed script. It displays the first 10 lines of input; the number of displayed lines is right before the q command.

#!/usr/bin/sed -f
10q

Sample Script: Printing The Last Lines

Printing the last n lines rather than the first is more complex but indeed possible. The n is encoded in the second line, before the bang (“!“) character.

This script is similar to the tac script (above) in that it keeps the final output in the hold space and prints it at the end:

#!/usr/bin/sed -nf
1! {; H; g; }
1,10 !s/[^\n]*\n//
$p
h

Mainly, the scripts keeps a window of 10 lines and slides it by adding a line and deleting the oldest (the substitution command on the second line works like a D command but does not restart the loop).

The “sliding window” technique is a very powerful way to write efficient and complex sed scripts, because commands like P would require a lot of work if implemented manually.

To introduce the technique, which is fully demonstrated in the rest of this chapter and is based on the N, P and D commands, here is an implementation of tail using a simple “sliding window.”

This looks complicated but in fact the working concept is the same as the last script: after we have kicked in the appropriate number of lines, however, we stop using the hold space to keep inter-line state, and instead use N and D to slide pattern space by one line:

#!/usr/bin/sed -f
1h
2,10 {; H; g; }
$q
1,9d
N
D

Note how the first, second and fourth line are inactive after the first ten lines of input. After that, all the script does is: exiting on the last line of input, appending the next input line to pattern space, and removing the first line.

Sample Script: Make Duplicate Lines Unique

This script is an example of the art of using the N, P and D commands, probably the most difficult to master.

#!/usr/bin/sed -f
h
:b
# On the last line, print and exit
$b
N
/^\(.*\)\n\1$/ {
    # The two lines are identical.  Undo the effect of
    # the n command.
    g
    bb
}
# If the N command had added the last line, print and exit
$b
# The lines are different; print the first and go
# back working on the second.
P
D

As you can see, we maintain a 2-line window using P and D. This technique is often used in advanced sed scripts.

Sample Script: Print Duplicated Lines Of Input

This script prints only duplicated lines, like ‘uniq -d’.

#!/usr/bin/sed -nf
$b
N
/^\(.*\)\n\1$/ {
    # Print the first of the duplicated lines
    s/.*\n//
    p
    # Loop until we get a different line
    :b
    $b
    N
    /^\(.*\)\n\1$/ {
        s/.*\n//
        bb
    }
}
# The last line cannot be followed by duplicates
$b
# Found a different one.  Leave it alone in the pattern space
# and go back to the top, hunting its duplicates
D

Sample Script: Remove All Duplicated Lines

This script prints only unique lines, like ‘uniq -u’.

#!/usr/bin/sed -f
# Search for a duplicate line --- until that, print what you find.
$b
N
/^\(.*\)\n\1$/ ! {
    P
    D
}
:c
# Got two equal lines in pattern space.  At the
# end of the file we exit
$d
# Else, we keep reading lines with N until we
# find a different one
s/.*\n//
N
/^\(.*\)\n\1$/ {
    bc
}
# Remove the last instance of the duplicate line
# and go back to the top
D

Sample Script: Squeezing Blank Lines

Como exemplo final, aqui estão três scripts, de complexidade e velocidade crescentes, que implementam a mesma função que ‘ cat -s ‘, que está espremendo linhas em branco.

A primeira deixa uma linha em branco no começo e no fim, se já houver alguma.

#! / usr / bin / sed -f
# em linhas vazias, junte-se ao próximo
# Observe que há uma estrela no regexp
: x
/ ^ \ n * $ / {
N
bx
}
# agora, aperte todos '\ n', isso também pode ser feito por:
# s / ^ \ (\ n \) * / \ 1 /
s / \ n * / \
/

Este é um pouco mais complexo e remove todas as linhas vazias no início. Deixa uma única linha em branco no final, se houver alguma.

#! / usr / bin / sed -f
# excluir todas as linhas vazias iniciais
1, / ^. / {
/./!d
}
# em uma linha vazia nós a removemos e todos os seguintes
# linhas vazias, mas uma
: x
/./! {
N
s / ^ \ n $ //
tx
}

Isso remove as linhas em branco iniciais e finais. Também é o mais rápido. Note-se que os loops são completamente feitos com n e b , sem depender de sed para reiniciar o script automaticamente no final de uma linha.

#! / usr / bin / sed -nf
# excluir todos os espaços em branco (principais)
/./!d
# chegue aqui: para que haja um não vazio
: x
# imprima
p
# próximo
n
# tem caracteres? imprima novamente, etc ...
/./bx
# não, não tem caracteres: obteve uma linha vazia
: z
# chegar em seguida, se a última linha terminar aqui, então não há rastro
# linhas vazias são gravadas
n
# também está vazio? então ignore e chegue ao próximo ... isso vai
# remove TODAS as linhas vazias
/./!beleza
# todas as linhas vazias foram excluídas / ignoradas, mas temos um não vazio. Como
# o que queremos fazer é apertar, inserir uma linha em branco artificialmente
Eu\
bx

Limitações do GNU sed (e não-limitações)

Para aqueles que desejam escrever scripts sed portáteis , saiba que algumas implementações limitam os comprimentos de linha (para o padrão e os espaços de espera) a não mais que 4000 bytes. A norma POSIX especifica que implementações sed conformes devem suportar pelo menos 8192 bytes de comprimento de linha. O GNU sed não tem limite embutido no comprimento da linha; contanto que ele possa alocar mais memória (virtual), você pode alimentar ou construir linhas pelo tempo que desejar.

No entanto, a recursão é usada para lidar com subpadrões e repetição indefinida. Isso significa que o espaço de pilha disponível pode limitar o tamanho do buffer que pode ser processado por certos padrões.

Expressões regulares estendidas

A única diferença entre expressões regulares básicas e estendidas está no comportamento de alguns caracteres: ‘ ? ‘,’ + ‘, parênteses e chaves (‘ {} ‘). Embora expressões regulares básicas exijam que elas sejam escapadas se você quiser que elas se comportem como caracteres especiais, ao usar expressões regulares estendidas, você deve escapá-las se desejar que elas correspondam a um caractere literal.

Por exemplo:

Exemplos

sed G myfile.txt> newfile.txt

Espaços duplos o conteúdo do arquivo myfile.txt e grava a saída no arquivo newfile.txt .

sed = meuarquivo.txt | sed 'N; s / \ n / \. / '

Prefixa cada linha do myfile.txt com um número de linha, um ponto e um espaço e exibe a saída.

sed 's / teste / exemplo / g' myfile.txt> newfile.txt

Procura a palavra ” teste ” em myfile.txt e substitui cada ocorrência pela palavra ” exemplo “.

sed -n '$ =' meuarquivo.txt

Conta o número de linhas em myfile.txt e exibe os resultados.

Comandos relacionados

awk – Intérprete para a linguagem de programação de processamento de texto AWK.
ed – Um simples editor de texto.
grep – Filtra o texto que corresponde a uma expressão regular.
substituir – Um utilitário de substituição de cadeia.